Indhold

# Identifikation af operativsystemet

Identifikation af operativsystemet kan udføres med Python- eller Basic-sprog.

## Brug af en Python-klasse:

            """ the_module """
            import os, platform
            class Platform():
                @property
                def ComputerName(self): return platform.node()
                @property
                def DirSeparator(self): return os.sep
                @property
                def isLinux(self): return (self.OSName=='Linux')
                @property
                def isMacOSX(self): return (self.OSName=='Darwin')
                @property
                def isWindows(self): return (self.OSName=='Windows')
                @property
                def OSName(self): return platform.system()
                @property
                def PathDelimiter(self): return os.pathsep

## Brug af et Basci-klassemodul:

LibreOffice Basic mangler medfødt genkendelse af MacOS X. Genkendelse af platform er mulig ved hjælp af LibreOffice Application Programming Interface (API).

            '''Modulnavn: Platform'''
            Option Compatible
            Option ClassModule
            Option Explicit

            Public Property Get ComputerName As String
                If isWindows Then ComputerName = Environ("ComputerName")
            End Property ' Platform.ComputerName

            Public Property Get DirSeparator As String
                DirSeparator = GetPathSeparator()
            End Property ' Platform.DirSeparator

            Public Property Get IsLinux As Boolean
                isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well
            End Property ' Platform.isLinux

            Public Property Get IsMacOSX As Boolean
                isMacOSX = ( OSName="MAC" )
            End Property ' Platform.isMacOSX

            Public Property Get IsWindows As Boolean
                isWindows = ( GetGUIType()=1 )
            End Property ' Platform.isWindows

            Public Property Get OSName As String
                ' Returner platformnavne som "MAC". "UNIX" og "WIN".
                ' Udledt fra funktionen "Tools.UCB..ShowHelperDialogue"
                With GlobalScope.Basiclibraries
                    If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
                End With
                Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
                keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
                OSName = keyNode.GetByName("System")
            End Property ' Platform.OSName

            Public Property Get PathDelimiter As String
                Select Case OSName
                    Case "MAC", "UNIX" : PathDelimiter = ":"
                    Case "WIN" : PathDelimiter = ";"
                 End Select
            End Property ' Platform.PathDelimiter

Miljøvariablen ComputerName er kun tilgængelig for Windows. Basic-kald til Python-makroer hjælper dig med at overvinde begrænsningerne i LibreOffice Basic.

## Eksempler:

Med Python

>>> from < the_module > import Platform

>>> print(Platform().isMacOSX) # objektegenskaber

True

>>> input(Platform().OSName) # objekt-egenskab

Darwin

Fra menuen Funktioner ▸ Makroer ▸ Kør makro....

            from < the_module > import Platform
            import screen_io as ui
            p = Platform()
            ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)

Med LibreOffice Basic

            Sub Platform_example()
                Dim p As New Platform ' instans af platform-klassen
                MsgBox p.isLinux ' objektegenskab
                Print p.isWindows, p.OSName ' objektegenskaber
            End Sub ' Platform_example

• ScriptForge.Platform-tjenesten giver en samling af egenskaber for det aktuelle afviklingsmiljø og -kontekst, som inkluderer identifikation af platformen.
• Omfattende identifikation af operativsystem-navnet er tilgængelig fra Calc-formlen INFO("system").

Relaterede emner

Input/Output til skræm

GetPathSeparator-funktion

Kalde Python-scripts fra Basic

Python programmeringseksempler

Hjælp til LibreOffice Pythonscripts