Indhold

# Funktionen MIDDEL.HVIS (på engelsk: AVERAGEIF)

Returnerer det aritmetiske gennemsnit af alle celler i et område der opfylder en given betingelse. Funktionen MIDDEL.HVIS (på engelsk: AVERAGEIF) summerer alle resultater der svarer til den logiske test, og dividerer summen med antallet af valgte værdier.

Denne funktion er tilgængelig siden LibreOffice 4.0.

### Syntaks

=MIDDEL.HVIS(Område; Kriterium [; Område_for_middel ])

Område – påkrævet argument. Et område, navnet på et navngivet område eller en etiket for en kolonne eller en række, som indeholder gennemsnitstal, tal eller tekst for betingelserne.

Kriterium1: Et kriterium er et tekstudtryk beregnet fra en enkelt cellereference, en formel, et tal eller en tekst. Det bruges i sammenligninger med celleindhold.

En henvisning til en tom celle fortolkes som den numeriske værdi 0.

Et matchende udtryk kan være:

- Et tal eller en logisk værdi. Et overensstemmende celleindhold er lig med tallet eller den logiske værdi.

- En værdi, som begynder med en sammenligning (<, <=, =, >, >=, <>).

  For = passer en tom værdi med en tom celle.

  For <> passer en tom værdi med en ikke-tom celle.

  For <> passer en ikke-tom værdi med ethvert andet celleindhold end værdien, inklusive tomme celler.

  Bemærk: "=0" matcher ikke tomme celle.

  For = and <> gælder, at hvis værdien ikke er tom og ikke kan fortolkes som en talværdi eller undertype af tal, og hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er krydset af, så sker sammenligningen med hele celleindholdet. Hvis feltet ikke er afkrydset, sker sammenligning med enhver underdel af feltet, som passer med kriterierne.

- Anden tekstværdi. Hvis egenskaben Søgekriterier = og <> skal gælde for hele celler er sand, sker sammenligningen med med hele cellens indhold, hvis falsk, sker sammenligningen med enhver underdel af feltet som passer til kriterierne. Udtrykket kan indeholde tekst, tal, regulære udtryk eller jokertegn (hvis jokertegn i formler er slået til i beregningsindstillinger).

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Indstillinger Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til lokalisering, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

Område_for_middel – valgfrit. Det er et område af værdier, som der skal beregnes middelværdi (gennemsnit) for.

Hvis Område_for_middel ikke er angivet, bruges Område til både beregningen af middelværdien og søgningen i overensstemmelse med betingelsen. Hvis Område_for_middel er angivet, bruges Område udelukkende til test af betingelsen, mens Område_for_middel bruges til beregning af middelværdien.

Hvis en celle i et område af værdier, som der skal beregnes middelværdi for, er tom eller indeholder tekst, ignorerer funktionen MIDDEL.HVIS cellen.
Hvis hele området er tomt, kun indeholder tekst, eller hvis ingen værdier opfylder betingelserne (eller nogen kombination af dem), returnerer funktionen fejlen #DIV/0!.

### Eksempler

Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Sales | Revenue
2 | pensel | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | pennalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpelt brug

=MIDDEL.HVIS(B2:B6;"<35")

Beregner gennemsnittet for værdier i området B2:B6 som er mindre end 35. Returnerer 19, fordi anden række ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;"<"&MAX(B2:B6))

Beregner gennemsnittet for værdierne i det samme område, som er mindre end den maksimale værdi i dette område. Returnerer 19, fordi den højeste værdi (anden række) ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;">"&MINDSTE(B2:B6;1))

Beregner gennemsnittet af værdier i det samme område, som er større end den første mindste værdi i området. Returnerer 25, fordi den første mindste værdi (fjerde række) ikke medregnes i gennemsnittet.

#### Brug af Område_for_middel

=MIDDEL.HVIS(B2:B6;"<35";C2:C6)

Funktionen finder de værdier, som er mindre end 35 i området B2:B6, og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 145, fordi anden række ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;">"&MIN(B2:B6);C2:C6)

Funktionen finder de værdier fra området B2:B6, som er større end den mindste værdi og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 113,3, fordi fjerde række (hvor den mindste værdi er) ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;"<"&STØRSTE(B2:B6;2);C2:C6)

Denne funktion finder hvilke værdier fra området B2:B6 som er mindre end den næsthøjeste værdi i området B2:B6, og beregner gennemsnittet for de korresponderende værdier fra området C2:C6. Returnerer 180, fordi kun fjerde række indgår i beregningen.

#### Brug af regulære udtryk

=MIDDEL.HVIS(A2:A6;"pen";B2:B6)

Denne funktion finder de celler fra området A2:A6 som indeholder ordet “pen”, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Returnerer 35, fordi kun den anden række indgår i beregningen. Søgningen sker i området A2:A6, men værdierne returneres fra området B2:B6.

=MIDDEL.HVIS(A2:A6;"pen.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som begynder med “pen” og slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 27,5, fordi også ordet “pensel” lever op til betingelserne, og både første og anden række indgår i beregningen.

=MIDDEL.HVIS(A2:A6;".*bog.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som indeholder “bog” og starter eller slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 18,5, fordi kun tredje og fjerde række indgår i beregningen.

#### Reference til en celle som kriterium

Hvis du har brug for let at ændre et kriterium, kan du angive det i en separat celle og bruge en reference til denne celle i betingelsen i MIDDEL.HVIS-funktionen.

=MIDDEL.HVIS(A2:A6;".*"&E2&".*";B2:B6)

Denne funktion finder hvilke celler i området A2:A6 som indeholder en kombination af tegn som specificeres i E2 startende og sluttende med enhver kombination af tegn, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = bog, returnerer funktionen 18,5.

=MIDDEL.HVIS(B2:B6;"<&E2;C2:C6)

Denne funktion finder de celler fra området A2:A6 som er mindre end værdien specificeret i E2, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = 35, returnerer funktionen 145.

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

Relaterede emner

Wiki-side for funktionen MIDDEL.HVIS (på engelsk: AVERAGEIF).

MIDDEL (på engelsk: AVERAGE), MIDDELV (på engelsk: AVERAGEA), MAD (på engelsk: AVEDEV)

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, Funktionen MIDDEL.FLERE.HVIS (på engelsk: AVERAGEIFS, SUM.FLERE.HVIS (på engelsk: SUMIFS)

Liste over regulære udtryk